MT4のMACDについて

  • 末広 大祐
  • E-mail
  • 2018/11/08 (Thu) 10:07:50
山中先生、いつも貴重な情報ありがとうございます。
先週、夜トレで福永さんがMACDのパラメーターをデフォルトの半分、6.12.5に設定すると良いとチラッと言っていたので、早速マネパのハイパースピードで試したところ、ものすごく反応がよく、今後短期で使っていくことに決めました。通常トレードのメインはMT4を使っているので、mt4でもMACDを出したところ、見たことの無い表示で、見にくいので、2本線の表示に変える方法を検索し試しました。ナビゲーターからインディケーター、MACD右クリック、修正36行目をHISTOGURAMUからLINEに変更、Compile,再起動で2本線に変わるとなっているのですが、何度試しても、PCを換えても2本線に変わりません。ToolboxがErrorsになっているのが気になります。何が悪いのでしょうか?本当に2本線に変更でるのでしょうか?ご指導ください。よろしくお願いいたします。長文乱文失礼いたしました。

Re: MT4のMACDについて

  • 山中
  • 2018/11/08 (Thu) 16:10:24
下に私が作った改良型MACDのソースコードを貼っておきますので、コンパイルしてお使いください。2本のライン表示としたことに加えて、MACSとシグナルとの差をヒストグラムで表示したよくあるパターンの表示になっています(動作確認済みです)。

Re: MT4のMACDについて

  • 山中
  • 2018/11/08 (Thu) 16:14:53
//+------------------------------------------------------------------+
//| Custom MACD.mq4 |
//| Copyright 2005-2014, MetaQuotes Software Corp. |
//| http://www.mql4.com |
//+------------------------------------------------------------------+
#property copyright "2005-2014, MetaQuotes Software Corp."
#property link "http://www.mql4.com"
#property description "MACD with Histogram" //modified by 山中(Yamanaka 部分を修正・追加)
#property strict

#include <MovingAverages.mqh>

//--- indicator settings
#property indicator_separate_window
#property indicator_buffers 4 //Yamanaka
#property indicator_color1 Blue
#property indicator_color2 Red
#property indicator_color3 Gray //Yamanaka
#property indicator_width3 2 //Yamanaka
#property indicator_color4 Lime //Yamanaka

//--- indicator parameters
input int InpFastEMA=12; // Fast EMA Period
input int InpSlowEMA=26; // Slow EMA Period
input int InpSignalSMA=9; // Signal SMA Period
input int InpHistSMA=1; // Histogram SMA Period

//--- indicator buffers
double ExtMacdBuffer[];
double ExtSignalBuffer[];
double ExtHistogramBuffer[]; //Yamanaka
double ExtHistogramMABuffer[]; //Yamanaka
//--- right input parameters flag
bool ExtParameters=false;

//+------------------------------------------------------------------+
//| Custom indicator initialization function |
//+------------------------------------------------------------------+
int OnInit(void)
{
IndicatorDigits(Digits+1);
//--- drawing settings
SetIndexStyle(0,DRAW_LINE);
SetIndexStyle(1,DRAW_LINE);
SetIndexStyle(2,DRAW_HISTOGRAM); //Yamanaka
SetIndexStyle(3,DRAW_LINE); //Yamanaka
SetIndexDrawBegin(1,InpSignalSMA);

//--- indicator buffers mapping
SetIndexBuffer(0,ExtMacdBuffer);
SetIndexBuffer(1,ExtSignalBuffer);
SetIndexBuffer(2,ExtHistogramBuffer); //Yamanaka
SetIndexBuffer(3,ExtHistogramMABuffer); //Yamanaka

//--- name for DataWindow and indicator subwindow label
IndicatorShortName("MACD("+IntegerToString(InpFastEMA)+","+IntegerToString(InpSlowEMA)+","+IntegerToString(InpSignalSMA)+","+IntegerToString(InpHistSMA)+")");
SetIndexLabel(0,"MACD");
SetIndexLabel(1,"Signal");
SetIndexLabel(2,"Histogram"); //Yamanaka
SetIndexLabel(3,"HistogramMA"); //Yamanaka

//--- check for input parameters
if(InpFastEMA<=1 || InpSlowEMA<=1 || InpSignalSMA<=1 || InpFastEMA>=InpSlowEMA)
{
Print("Wrong input parameters");
ExtParameters=false;
return(INIT_FAILED);
}
else
ExtParameters=true;
//--- initialization done
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Moving Averages Convergence/Divergence |
//+------------------------------------------------------------------+
int OnCalculate (const int rates_total,
const int prev_calculated,
const datetime& time[],
const double& open[],
const double& high[],
const double& low[],
const double& close[],
const long& tick_volume[],
const long& volume[],
const int& spread[])
{
int i,limit;
//---
if(rates_total<=InpSignalSMA || !ExtParameters)
return(0);
//--- last counted bar will be recounted
limit=rates_total-prev_calculated;
if(prev_calculated>0)
limit++;
//--- macd
for(i=0; i<limit; i++)
ExtMacdBuffer[i]=iMA(NULL,0,InpFastEMA,0,MODE_EMA,PRICE_CLOSE,i)-iMA(NULL,0,InpSlowEMA,0,MODE_EMA,PRICE_CLOSE,i);
//--- signal
for(i=0; i<limit; i++) //Yamanaka
ExtSignalBuffer[i]=iMAOnArray(ExtMacdBuffer,0,InpSignalSMA,0,0,i); //Yamanaka
//--- histogram
for(i=0; i<limit; i++) //Yamanaka
ExtHistogramBuffer[i]=ExtMacdBuffer[i]-ExtSignalBuffer[i]; //Yamanaka
//--- histogramMA
for(i=0; i<limit; i++) //Yamanaka
ExtHistogramMABuffer[i]=iMAOnArray(ExtHistogramBuffer,0,InpHistSMA,0,0,i); //Yamanaka
//--- done
return(rates_total);
}
//+------------------------------------------------------------------+

Re: MT4のMACDについて

  • 末広 大祐
  • E-mail
  • 2018/11/08 (Thu) 21:40:06
早急に返答いただきまして、ありがとうございます。
(投稿前に、内容をプレビューして確認できます)